Acheter ce capteur

• Les 2 modules radio de ce tutoriel 

Voir des vidéos liées

• En prévision

//************************************************************************//

//               -- EXEMPLE : TRANSMISSION RADIO SANS CODAGE --           //

//                         >> Partie ÉMETTEUR <<                          //        //                                                                        //

//                   David Souder pour www.duinoedu.com                   //

//                               Version 0.1                              //

//                        Programme libre de droit                        //

//************************************************************************//

/*

UTILITE DU PROGRAMME :

Permet de transmettre des petits messages texte par ondes radio entre 2 cartes Arduino ou DuinoEDU.

*/

/*

LIBRAIRIE UTILISEE : VirtualWire ( Nous en parlerons plus tard. Ne téléchargez rien pour l’instant).

*/

/*

MODULES :

Nous allons utiliser les modules Tracker Radio TRACK1

http://duinoedu.com/store/index.php?id_product=92&controller=product

*/

//--- Ne fait que contenir le n° du trou utilisé par le module

int brocheEmetteur = 2;

//A-- Vérifiez ensuite que vous avez bien la librairie VirtualWire. Pour cela, dans votre logiciel Arduino, faites : “Croquis” puis “Importer bibliothèque”. Si dans la liste vous trouvez “VirtualWire”, alors vous pouvez passer l’étape de téléchargement et aller directement au “B”. Si au contraire vous n’avez pas ce fichier faire ce qui suit de T1 à T4 puis passez au “B” :

/*

  T1 : cliquez sur ce lien de téléchargement :

      > http://www.open.com.au/mikem/arduino/VirtualWire/VirtualWire-1.14.zip

  T2 : sauvegardez le fichier sur votre bureau par exemple

  T2 : Dans Arduino, cliquez sur :

      > “Croquis” puis “Importer bibliothèque” puis “Add library”

  T3 : allez chercher le fichier .zip précédent (a priori sur votre bureau)

  T4 : votre librairie est maintenant connue d’Arduino.

*/

//B-- Nous allons ajouter la bibliothèque à notre programme

#include <VirtualWire.h>

//----- On va créer ou utiliser une partie dite d’initialisation = setup !
void setup() 

{ 

  //--- Nous allons donner quelques paramètres liés au transfert

    //--Le signal doit-il être inversé ? => OUI

    vw_set_ptt_inverted(true);

    //--Quelle vitesse pour cette transmission ? => 2000 bits / seconde

    vw_setup(2000);

    //--Sur quelle broche sera branchée la pointe ATAD du module émetteur => 2

    vw_set_tx_pin(brocheEmetteur);

} 

//----- On va créer ou utiliser une partie dite boucle = loop
void loop() 
{ 

  //--- Écrivons le message à transmettre dans une variable

  const char *monMessage = "Bonjour !";   // Notez l’*, c’est un pointeur !

  //--- Nous allons calculer la longueur de la chaîne pointée par monMessage

  int longeurChaine = strlen(monMessage); // Elle est normalement de 9+1=10

  //--- Transmettons effectivement le message.

    //  Il faut utiliser la variable pointeur

    //  Il faut s’ssaurer du bon format : uint8_t (entier positif 8 bits)

    //  Il faut aussi donner la longeur de la chaîne à transmettre.

  vw_send( (uint8_t *)monMessage, longeurChaine );

  //--- Nous attendons ensuite que la transmission soit terminée

  vw_wait_tx();

  //--- Nous faisons une pause pour limiter le nombre de messages

  delay(1000);                            // Nous attendons 1 seconde

  //----- N’oubliez pas de fermer les “crochets” “{......}

  // Comme c’est une boucle, le programme va revenir tout seul au début

  // Mais attention ! le setup() n’est exécuté qu’une seule fois

}

// Cet exemple n’est pas clair ? Contactez-nous !

//************************************************************************//

//               -- EXEMPLE : TRANSMISSION RADIO SANS CODAGE --           //

//                         >> Partie RÉCEPTEUR <<                          //        //                                                                        //

//                   David Souder pour www.duinoedu.com                   //

//                               Version 0.1                              //

//                        Programme libre de droit                        //

//************************************************************************//

/*

UTILITE DU PROGRAMME :

Permet de recevoir des petits messages texte par ondes radio entre 2 cartes Arduino ou DuinoEDU.

*/

/*

LIBRAIRIE UTILISEE : VirtualWire ( Nous en parlerons plus tard. Ne téléchargez rien pour l’instant).

*/

/*

MODULES :

Nous allons utiliser les modules Tracker Radio TRACK1

http://duinoedu.com/store/index.php?id_product=92&controller=product

*/

//--- Ne fait que contenir le n° du trou utilisé par le module

int brocheRecepteur = 3;

//A-- Vérifiez ensuite que vous avez bien la librairie VirtualWire. Pour cela, dans votre logiciel Arduino, faites : “Croquis” puis “Importer bibliothèque”. Si dans la liste vous trouvez “VirtualWire”, alors vous pouvez passer l’étape de téléchargement et aller directement au “B”. Si au contraire vous n’avez pas ce fichier, faire ce qui suit de T1 à T4 puis passez au “B”:

/*

  T1 : cliquez sur ce lien de téléchargement :

      > http://www.open.com.au/mikem/arduino/VirtualWire/VirtualWire-1.14.zip

  T2 : sauvegardez le fichier sur votre bureau, par exemple

  T2 : Dans Arduino, cliquez sur :

      > “Croquis” puis “Importer bibliothèque” puis “Add library”

  T3 : allez chercher le fichier .zip précédent (a priori sur votre bureau)

  T4 : votre librairie est maintenant connue d’Arduino.

*/

//B-- Nous allons ajouter la bibliothèque à notre programme

#include <VirtualWire.h>

//----- On va créer ou utiliser une partie dite d’initialisation = setup !
void setup() 

{ 

  //--- Nous allons donner quelques paramètres liés à la réception des données

    //--Le signal doit-il être inversé ? => OUI

    vw_set_ptt_inverted(true);

    //--Quelle vitesse pour cette transmission ? => 2000 bits / seconde

    vw_setup(2000);

    //--Sur quelle broche sera branchée la pointe DATA du module récep. => 3

    vw_set_rx_pin(brocheRecepteur);

    //--Faut-il démarrer l’écoute maintenant => oui

    vw_rx_start();       // Écoute active du récepteur

  //--- Nous allons activer le moniteur série (= messages sur ordinateur)

    //-- Activation du port série à 9600 bits par seconde

    Serial.begin(9600);

} 

//----- On va créer ou utiliser une partie dite boucle = loop
void loop() 
{ 

  //--- Nous allons récupérer la taille maximale de la mémoire tampon

    //--Cette valeur est stockée dans une constante VW...

    uint8_t tailleBuffer = VW_MAX_MESSAGE_LEN ;

  //--- Nous allons créer un tableau pour recevoir nos messages

    //--Création du tableau de récupération des messages de la bonne taille

    uint8_t tableauReception[ tailleBuffer ] ;

  //--- Nous allons faire un relevé de messages

    //--Si un message est reçu, le test sera “vrai” et une lecture sera faite

    if (vw_get_message(tableauReception, &tailleBuffer))

    {

      //-Il nous faut alors récupérer le message lettre par lettre

        //Nous créons une variable intermédiaire

        int monCompteur ;       // Doit contenir le n° d’une lettre

        //Nous créons ensuite une boucle pour afficher toutes les lettres

        for ( monCompteur=0 ; monCompteur<tailleBuffer ; monCompteur++)

        {

          //On affiche sur l’écran d’ordinateur la lettre 0 puis 1,2,3…

          Serial.write( tableauReception[monCompteur] );

        }

      //-Sautons une ligne avant d’afficher le message suivant

      Serial.println();

      Serial.println("-------------------");

    }

  //----- N’oubliez pas de fermer les “crochets” “{......}

  // Comme c’est une boucle, le programme va revenir tout seul au début

  // Mais attention ! le setup() n’est exécuté qu’une seule fois

}

//---- N’oubliez pas de cliquer sur la petite flèche pour “téléverser”

  // votre programme dans la carte Arduino...

  //---- N’oubliez pas de cliquer sur la petite loupe “moniteur série” pour

  // lire les SMS envoyés à l’ordinateur par ce programme.

  //---- Si vous obtenez des messages étranges, pensez à vérifier que la

  // vitesse en bas à droite de la petite fenêtre du moniteur série est

  // bien la même que celle définie par Serial.begin(...).

  // Elle est souvent à 9600 bits par seconde

//---- N’oubliez pas de TOUJOURS refermer la fenêtre de lecture des SMS

  // Si vous oubliez, vous ne comprendrez peut-être pas pourquoi il

  // vous est impossible de “Téléverser” votre programme à nouveau.

  // Prenez cette bonne habitude. REFERMEZ la fenêtre MONITEUR SERIE à chaque

  // fois qu’elle n’est plus utilisée…

// Cet exemple n’est pas clair ? Contactez-nous !