*****************.
* INICIO DE SECCION 1*.
*****************.
* El módulo 01 de la ENAHO tiene la variable de necesidad calórica de cada hogar, y de las calorías efectivamente adquiridas por el
* hogar, asi como también las variables que permiten identificar cada hogar de manera única.
*****************.

GET  FILE='C:\ENAHO\148-Modulo01\Enaho01-2006-100.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2006Q1.sav' /COMPRESSED.

GET  FILE='C:\ENAHO\156-Modulo01\Enaho01-2006-100.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2006Q2.sav' /COMPRESSED.

GET  FILE='C:\ENAHO\162-Modulo01\Enaho01-2006-100.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2006Q3.sav' /COMPRESSED.

GET  FILE='C:\ENAHO\168-Modulo01\Enaho01-2006-100.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2006Q4.sav' /COMPRESSED.

GET  FILE='C:\ENAHO\200-Modulo01\Enaho01-2008-100.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2008Q1.sav' /COMPRESSED.

GET  FILE='C:\ENAHO\202-Modulo01\Enaho01-2008-100_2.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2008Q2.sav' /COMPRESSED.

GET  FILE='C:\ENAHO\213-Modulo01\Enaho01-2008-100.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2008Q3.sav' /COMPRESSED.

GET  FILE='C:\ENAHO\217-Modulo01\Enaho01-2008-100.sav'
       /KEEP=año TO hogar reqcalam caloria.
SAVE OUTFILE='C:\ENAHO\vivienda_2008Q4.sav' /COMPRESSED.

*****************.
* Los ocho trimestres de 2006 y 2008 son apilados con las variables necesarias.
*****************.
ADD FILES /FILE='C:\ENAHO\vivienda_2006Q1.sav'
                  /FILE='C:\ENAHO\vivienda_2006Q2.sav'
                  /FILE='C:\ENAHO\vivienda_2006Q3.sav'
                  /FILE='C:\ENAHO\vivienda_2006Q4.sav'
                  /FILE='C:\ENAHO\vivienda_2008Q1.sav'
                  /FILE='C:\ENAHO\vivienda_2008Q2.sav'
                  /FILE='C:\ENAHO\vivienda_2008Q3.sav'
                  /FILE='C:\ENAHO\vivienda_2008Q4.sav'.

*****************.
* Se calcula una variable dicotómica para déficit calórico.
*****************.
COMPUTE DEFICIT = caloria - reqcalam .
RECODE  DEFICIT  (Lowest thru 0=1)  (0 thru Highest=0) .
VARIABLE LABEL DEFICIT 'Déficit Calórico' .
VALUE LABEL DEFICIT 0 'No tiene' 1 'Si tiene' .

*****************.
* Se construye la llave que identifica de manera única a cada hogar.
*****************.
STRING llave(A15).
COMPUTE llave=CONCAT(año, mes, conglome, vivienda, hogar).
SORT CASES BY llave.
SAVE OUTFILE='C:\ENAHO\CALORIAS_HOGAR.sav'
         /KEEP=llave deficit /COMPRESSED.
************************.
* FIN DE SECCION 1*.
************************.

*****************.
* INICIO DE SECCION 2*.
*****************.
* El módulo 02 de la ENAHO tiene el factor de expansión de la población, así como también las variables que permiten identificar
* cada hogar de manera única.
*****************.
GET FILE='C:\ENAHO\148-Modulo02\Enaho01-2006-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2006Q1.sav' /COMPRESSED.

GET FILE='C:\ENAHO\156-Modulo02\Enaho01-2006-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2006Q2.sav' /COMPRESSED.

GET FILE='C:\ENAHO\162-Modulo02\Enaho01-2006-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2006Q3.sav' /COMPRESSED.

GET FILE='C:\ENAHO\168-Modulo02\Enaho01-2006-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2006Q4.sav' /COMPRESSED.

GET FILE='C:\ENAHO\200-Modulo02\Enaho01-2008-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2008Q1.sav' /COMPRESSED.

GET FILE='C:\ENAHO\202-Modulo02\Enaho01-2008-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2008Q2.sav' /COMPRESSED.

GET FILE='C:\ENAHO\213-Modulo02\Enaho01-2008-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2008Q3.sav' /COMPRESSED.

GET FILE='C:\ENAHO\217-Modulo02\Enaho01-2008-200.sav'
      /KEEP=año TO facpob.
SAVE OUTFILE='C:\ENAHO\persona_2008Q4.sav' /COMPRESSED.

*****************.
* Los ocho trimestres de 2006 y 2008 son apilados con las variables necesarias.
*****************.
ADD FILES /FILE='C:\ENAHO\persona_2006Q1.sav'
                  /FILE='C:\ENAHO\persona_2006Q2.sav'
                  /FILE='C:\ENAHO\persona_2006Q3.sav'
                  /FILE='C:\ENAHO\persona_2006Q4.sav'
                  /FILE='C:\ENAHO\persona_2008Q1.sav'
                  /FILE='C:\ENAHO\persona_2008Q2.sav'
                  /FILE='C:\ENAHO\persona_2008Q3.sav'
                  /FILE='C:\ENAHO\persona_2008Q4.sav'.

*****************.
* Se construye la llave que identifica de manera única a cada hogar.
*****************.
STRING llave(A15).
COMPUTE llave=CONCAT(año, mes, conglome, vivienda, hogar).
SORT CASES BY llave.
SAVE OUTFILE='C:\ENAHO\UBIGEO_PERSONAS.sav'
         /KEEP=llave ubigeo facpob /COMPRESSED.
************************.
* FIN DE SECCION 2*.
************************.

*****************.
* INICIO DE SECCION 3*.
*****************.
* Se asocia a cada persona con la variable dicotómica del déficit calórico del hogar, de tal modo que la característica del.
* hogar se propaga a las personas que pertenecen a dicho hogar.
*****************.
MATCH FILES /FILE='C:\ENAHO\UBIGEO_PERSONAS.sav'
                      /TABLE='C:\ENAHO\CALORIAS_HOGAR.sav'
                      /BY llave .
*****************.
* El factor de expansión que era trimestral se divide por 4 para obtener resultados anuales.
*****************.
COMPUTE facpob_a=facpob/4.
*****************.
* Se calcula la variable que identifica cada región a partir de la variable UBIGEO, que contiene departamento, provincia, y distrito.
*****************.
COMPUTE prov = NUMBER(SUBSTR(UBIGEO,1,4),F4) .
RECODE  prov  (1501=0000)  (0701=0000)  .
COMPUTE regi = TRUNC(PROV/100) .
VARIABLE LABELS regi 'Región'.
VALUE LABELS regi
0 'Lima y Callao'
1 'Amazonas'
2 'Ancash'
3 'Apurimac'
4 'Arequipa'
5 'Ayacucho'
6 'Cajamarca'
8 'Cuzco'
9 'Huancavelica'
10 'Huánuco'
11 'Ica'
12 'Junín'
13 'La Libertad'
14 'Lambayeque'
15 'Lima Provincias'
16 'Loreto'
17 'Madre de Dios'
18 'Moquegua'
19 'Pasco'
20 'Piura'
21 'Puno'
22 'San Martín'
23 'Tacna'
24 'Tumbes'
25 'Ucayali' .
*****************.
* Se calcula la variable que identifica cada fecha a partir de la variable "llave".
*****************.
COMPUTE fecha = NUMBER(SUBSTR(llave,1,4),F4) .
*****************.
* El factor de expansión standarizado se obtiene para efectuar pruebas de hipótesis.
*****************.
IF (fecha=2006) facpob_s=96146*facpob_a/29275286.
IF (fecha=2008) facpob_s=94690*facpob_a/30416415.
EXECUTE.
*****************.
* Como medida de control se obtiene el número absoluto de personas identificadas a nivel de hogar.
*****************.
CROSSTABS
  /TABLES=regi  BY deficit  BY fecha  /FORMAT= AVALUE TABLES
  /CELLS= COUNT  /COUNT ROUND CELL .
*****************.
* Se aplica el factor de expansión, y se obtienen las incidencias porcentuales.
*****************.
WEIGHT  BY facpob_a .
CROSSTABS
  /TABLES=regi  BY deficit  BY fecha  /FORMAT= AVALUE TABLES
  /CELLS= ROW  /COUNT ROUND CELL .
*****************.
* Se aplica el factor de expansión estandarizado, y se obtienen las mismas incidencias porcentuales.
*****************.
WEIGHT  BY facpob_s .
CROSSTABS
  /TABLES=regi  BY deficit  BY fecha  /FORMAT= AVALUE TABLES
  /CELLS= ROW  /COUNT ROUND CELL .
*****************.
* Se ordenan los casos por región y se efectúa una prueba T de igualdad de medias.
*****************.
T-TEST  GROUPS = fecha(2006 2008)  /MISSING = ANALYSIS
            /VARIABLES = DEFICIT  /CRITERIA = CI(.999) .
SORT CASES BY regi.
SPLIT FILE  LAYERED BY regi .
T-TEST  GROUPS = fecha(2006 2008)  /MISSING = ANALYSIS
            /VARIABLES = DEFICIT  /CRITERIA = CI(.999) .

************************.
* FIN DE SECCION 3*.
************************.